티스토리 뷰
엑셀 SUMIFS 함수 사용법, 부등호, 두가지 조건 합계 구하기
엑셀에서 두 가지 이상의 조건을 만족하는 경우 합계를 구할 때 SUMIFS 함수를 사용합니다.
SUMIF 함수는 한 가지의 조건을 만족하는 경우 합계를 구할 때 사용합니다.
SUMIFS 함수는 주로 2~3개 정도의 조건을 만족하는 경우 특정 셀들의 합계를 구할 때 사용하지만 총 127가지의 조건까지 입력이 가능합니다.
1번째 인수는 조건을 만족할 때 합계를 구할 셀들의 범위를 지정합니다.
인수의 이름이 Criteria_range 인 경우는 조건을 적용시킬 셀 범위를 지정합니다.
인수의 이름이 Criteria 인 경우는 조건을 지정합니다.
엑셀 SUMIFS 함수 사용법, 부등호 사용법
엑셀의 SUMIFS 함수 사용법을 설명하기 위해 위의 그림과 같은 데이터를 이용해 값을 추출해 보겠습니다.
그리고 조건으로 자주 사용하는 부등호를 적용하여 SUMIFS 함수 사용법을 설명하도록 하겠습니다.
◈ 조건 1 : 구분 항목이 과일이면서 단가가 250 이상인 것의 수량 합계는?
◈ 수식 : =SUMIFS(C4:C15,A4:A15,"과일",D4:D15,">=250")
◈ 결과 : 77
◈ 설명
SUMIFS 함수의 1번째 인수는 조건을 만족할 경우 구할 합계의 범위이므로 수량 항목의 범위인 C4:C15를 지정합니다.
2번째 인수는 구분 항목에 대한 조건이므로 A4:A15를 지정합니다.
3번째 인수는 구분 항목이 과일이므로 "과일"을 지정합니다.
4번째 인수는 단가에 대한 조건이므로 D4:D15를 지정합니다.
5번째 인수는 단가가 250 이상인 경우이므로 ">=250"을 입력합니다.
위의 조건을 만족하는 셀은 복숭아 34와 ?포도 43 이므로 합계는 77 입니다.
SUMIFS 함수에서 조건을 적용할 때 부등호는 숫자보다 앞에 표시하며, "부등호 숫자"형식이 됩니다.
"이상"은 "크거나 같다"라는 뜻으로 ">=숫자"를 사용하고,
"이하"는 "작거나 같다"라는 뜻으로 "<=숫자"를 사용하며,
"초과"는 "크다"라는 뜻으로 ">숫자"를 사용하고,
"미만"은 "작다"라는 뜻으로 "<숫자"를 사용합니다.
◈ 조건 2 : 구분 항목이 야채 이면서 단가가 200 이하인 것의 수량 합계는?
◈ 수식 : =SUMIFS(C4:C15,A4:A15,"야채",D4:D15,"<=200")
◈ 결과 : 115
◈ 설명
1번째 인수는 조건을 만족할 경우 구할 합계의 범위이므로 수량 항목의 범위인 C4:C15를 지정합니다.
2번째 인수는 구분 항목에 대한 조건이므로 A4:A15를 지정합니다.
3번째 인수는 구분 항목이 야채이므로 "야채"를 지정합니다.
4번째 인수는 단가에 대한 조건이므로 D4:D15를 지정합니다.
5번째 인수는 단가가 200 이하인 경우이므로 "<=200"을 입력합니다.
위의 조건을 만족하는 셀은 고구마 42, 오이 17, 양파 40 이므로 합계는 99 입니다.
◈ 조건 3 : 구분 항목이 지정되지 않았으면서 단가가 300 보다 큰 것의 수량 합계는?
◈ 수식 : =SUMIFS(C4:C15,A4:A15,"",D4:D15,">300")
◈ 결과 : 50
◈ 설명
1번째 인수는 조건을 만족할 경우 구할 합계의 범위이므로 수량 항목의 범위인 C4:C15를 지정합니다.
2번째 인수는 구분 항목에 대한 조건이므로 A4:A15를 지정합니다.
3번째 인수는 구분 항목이 지정되지 않은 것을 찾으므로 ""(따옴표 2개)를 지정합니다.
4번째 인수는 단가에 대한 조건이므로 D4:D15를 지정합니다.
5번째 인수는 단가가 300 보다 큰 경우이므로 ">300"을 입력합니다.
위의 조건을 만족하는 셀은 *소시지 50 이므로 합계는 50 입니다.
◈ 조건 4 : 과일 중에서 종류가 "복"으로 시작하는 것의 수량 합계는?
◈ 수식 : =SUMIFS(C4:C15,A4:A15,"과일",B4:B15,"복*")
◈ 결과 : 34
◈ 설명
1번째 인수는 조건을 만족할 경우 구할 합계의 범위이므로 수량 항목의 범위인 C4:C15를 지정합니다.
2번째 인수는 구분 항목에 대한 조건이므로 A4:A15를 지정합니다.
3번째 인수는 구분 항목이 과일이므로 "과일"을 지정합니다.
4번째 인수는 종류에 대한 조건이므로 B4:B15를 지정합니다.
5번째 인수는 "복" 으로 시작하는 종류를 찾으므로 "복*"로 와일드카드 * 를 사용합니다.
와일드카드 중 *(애스터리스크, asterisk) 의 의미는 모든 글자를 의미하며, "복*"는 복으로 시작하는 모든 글자를 의미합니다.
종류가 "복"으로 시작하는 과일은 복숭아 하나 뿐이므로 합계는 34 입니다.
◈ 조건 5 : 종류의 글자수가 3자이면서 단가가 250 이상인 것의 수량 합계는?
◈ 수식 : =SUMIFS(C4:C15,B4:B15,"???",D4:D15,">=250")
◈ 결과 : 96
◈ 설명
1번째 인수는 조건을 만족할 경우 구할 합계의 범위이므로 수량 항목의 범위인 C4:C15를 지정합니다.
2번째 인수는 종류 항목에 대한 조건이므로 B4:B15를 지정합니다.
3번째 인수는 종류의 글자수가 3자이므로 한 글자를 의미하는 와일드카드인 ?(물음표)를 3개 사용하여 "???"를 지정합니다.
4번째 인수는 단가에 대한 조건이므로 D4:D15를 지정합니다.
5번째 인수는 단가가 250 이상인 것을 찾으므로 ">=250"을 지정합니다.
종류의 글자수가 3자이면서 단가가 250 이상인 것은 복분자 19, 복숭아 34, ?포도 43 이므로 합계는 96 입니다.
◈ 조건 6 : 종류가 "자"로 끝나면서 단가가 300 이상인 것의 수량 합계는?
◈ 수식 : =SUMIFS(C4:C15,B4:B15,"*자",D4:D15,">=300")
◈ 결과 : 23
◈ 설명
1번째 인수는 조건을 만족할 경우 구할 합계의 범위이므로 수량 항목의 범위인 C4:C15를 지정합니다.
2번째 인수는 종류 항목에 대한 조건이므로 B4:B15를 지정합니다.
3번째 인수는 종류가 "자"로 끝나는 것을 찾아야 하므로 와일드카드 *(애스터리스크)에 "자"를 붙여서 "*자"를 지정합니다.
4번째 인수는 단가에 대한 조건이므로 D4:D15를 지정합니다.
5번째 인수는 단가가 300 이상인 것을 찾으므로 ">=300"을 지정합니다.
종류의 "자"로 끝나는 것은 복분자와 감자가 있지만 단가가 300 이상인 것은 감자 뿐이므로 합계는 23 입니다.
◈ 조건 7 : 종류가 "*"로 시작하면서 수량이 30 이상인 것의 단가 합계는?
◈ 수식 : =SUMIFS(D4:D15,B4:B15,"~**",C4:C15,">=30")
◈ 결과 : 400
◈ 설명
1번째 인수는 조건을 만족할 경우 구할 합계의 범위이므로 단가 항목의 범위인 D4:D15를 지정합니다.
2번째 인수는 종류 항목에 대한 조건이므로 B4:B15를 지정합니다.
3번째 인수는 종류가 "*"로 시작하는 것을 찾아야 하는데 시작문자가 와일드카드 *(애스터리스크) 이므로 와일드카드 앞에 ~(물결표시)를 넣어서 "~**"를 지정합니다.
4번째 인수는 수량에 대한 조건이므로 C4:C15를 지정합니다.
5번째 인수는 수량이 30 이상인 것을 찾으므로 ">=30"을 지정합니다.
종류의 "*"로 시작하면서 수량이 30 이상인 것은 "*소시지" 뿐이므로 단가 합계는 400 입니다.
◈ 조건 8 : 종류가 "?"로 시작하면서 수량이 20 이하인 것의 단가 합계는?
◈ 수식 : =SUMIFS(D4:D15,B4:B15,"~?*",C4:C15,">=20")
◈ 결과 : 320
◈ 설명
1번째 인수는 조건을 만족할 경우 구할 합계의 범위이므로 단가 항목의 범위인 D4:D15를 지정합니다.
2번째 인수는 종류 항목에 대한 조건이므로 B4:B15를 지정합니다.
3번째 인수는 종류가 "?"로 시작하는 것을 찾아야 하는데 시작문자가 와일드카드 ?(물음표, question mark) 이므로 와일드카드 앞에 ~(물결표시)를 넣어서 "~?*"를 지정합니다.
4번째 인수는 수량에 대한 조건이므로 C4:C15를 지정합니다.
5번째 인수는 수량이 20 이상인 것을 찾으므로 ">=20"을 지정합니다.
종류의 "?"로 시작하면서 수량이 20 이상인 것은 "?포도" 뿐이므로 단가 합계는 320 입니다.
저는 위 상품을 소개하면서 포인트를 받았습니다.